https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

Stacked column charts are hard to visualise especially when you have more than four “stacks” and if one of them predominates its harder to visualise even with using the right colour gradients.

There needs to be a better way to visualise stacked column charts and a recent problem I have been working on provided me with an opportunity to do so. I wanted to visualise client debts by month broken down into five bands. The chart looked like this when all the formatting was applied

As you can see its hard to visualise this chart as your eyes go back and forth between the chart and the legend to see what the bands are. You can click on the legend like below to isolate an individual band but its not the best user experience. So lets see if we can improve upon this.

Our Debt table looks like this and it is connected to the Band table having Band as a column in a many to one relationship

We first define a measure which will give the debt for the selected band.

Selected Debt =
IF ( ISFILTERED ( Band[Band] ), SUM ( Debt[Amount] ), 0 )

We then define five measures for the five bands. An example is given below

Debt <30Days =
VAR selband =
    VALUES ( Band[Band] )
RETURN
    IF (
        “<30 Days” IN selband
            && ISFILTERED ( Band[Band] ),
        0,
        CALCULATE ( SUM ( Debt[Amount] ), Band[Band] = “<30 Days” )
    )

What we are doing here is anytime the band “<30 Days” is selected in the slicer and if the column band is filtered the debt amount is shown as zero else the debt amount is shown for that band. This is the opposite of what we normally do because we already have a measure [Selected Debt] which gives the debt amount for the selected band.

We define the other four measures replacing “<30 Days” with the appropriate band.

We also define another measure to get the percentage debt in the selected bands

Selected Debt% =
[Selected Debt] / CALCULATE ( SUM ( Debt[Amount] ), ALL ( Band[Band] ) )

We are ready to visualise the data. In the stacked column chart visual drag Month into Axis, and the first six measures which we defined into Values. Make the colour of [Selected Debt] measure as something which stands out (say Orange) and others as grey. The set up should look like this

No band is highlighted as we have not yet selected a band from the slicer. Drag the Band column from the Band table into a slicer. Import the “Data story” custom visual and place it on the canvas and drag [Selected Debt%] into data values and under the Story section of the visual write this text “The selected band(s) account for # of all debts”

Now we are good to visualise our data

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the sixth post, we discussed how to isolate and visualise YTD data

In this post we will discuss how to dynamically calculate the yearly percentage sales of top N products and measure it against a target % value. The technique used is different than the one used in the previous post. In the previous post we plotted sales of top 10 products by filtering the visuals to give the top 10 sales. This gave us the sales of the global top 10 products for each year. However what we want is the sales of top 10 products for each year and plot it accordingly.

We will use the same data model as the previous post. Since we will be dynamically plotting the sales, we need to calculate two parameters, one for top N and the other for target %. Our topN parameter  and target % parameter will be defined like this. Make sure the ‘Add slicer to this page’ option is selected.

Next we will calculate the Top N sales measure incorporating the TopN value measure defined in previous step

TopN Sales =
VAR top10sales =
    ADDCOLUMNS (
        GENERATE (
            VALUES ( ‘Date'[Year] ),
            TOPN ( [TopN Value], VALUES ( Products[ProductID.Product] ), [Total Sales] )
        ),
        “TotalSalesTop10”, [Total Sales]
    )
RETURN
    SUMX ( top10sales, [TotalSalesTop10] )

The topN sales % is calculated as

Top 10 Sales % =
DIVIDE ( [TopN Sales], [Total Sales] )

In order to achieve strategic colouring we need to define three measures and compare the TopN sales % against the target measure

TopN Sales % Above Target =
IF ( [TopN Sales %] >= [Target % Value], [TopN Sales %], 0 )

TopN Sales % Below Target =
IF ( [TopN Sales %] < [Target % Value], [TopN Sales %], 0 )

Total Sales Remaining % =
1 – [TopN Sales % Above Target] – [TopN Sales % Below Target]

Now we are ready to plot. Create a line and stacked column chart and drag Year into Axis and drag the above three measures into Column values and drag Target % value into Line values. Under Data colours section of the chart give the following colours to the measures

You can interact with the chart by changing the TopN and Target % sliders and see the effect on the charts

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the fifth post, we showcased how to visually determine the difference in sales from a base year for different segments

In this instalment we will discuss how to visually display the top 10 products on a yearly basis

Creating a Top 10 chart in Power BI is very easy. You select the Products and apply a top 10 filter on it on the metric of your choice. But what if you wanted to create a top 10 chart for the products on a yearly basis.

This is easy as well. We create a bar chart and drag Year into Axis and [Total Sales] into Value and apply a top 10 filter on the visual on the ProductID.Product column. We also want to see what are the top products so we drag ProductID.Product column into Legend. The setup looks like this.

Now the Total Sales for all the years is $5.13bn so the above chart looks a bit suspicious. The maximum sales of the top 10 products for a year is in 2007 and its only $80mn. Lets investigate this further. Lets click on the ellipses on the top right hand corner and select Show as a table to get this view

We see some gaps in the data. In some years there are no sales against some products. So what is happening here ? The top 10 filter we applied on this chart is the top 10 products for all sales for all the years. Hence while there might be products like 449.Maximus UM-54 which is in the top 10 products for all years it may not be in the top 10 for some years. We take note of this and move on as for this exercise we do not need a chart which shows the yearly top 10 values. We will cover that in future posts.

Remove the ProductID.Product column from the legend in the chart. We want to highlight any product in the chart by selecting a product from a slicer. We place the ProductID.Product column into a slicer and apply a top 10 filter on it so that only the top 10 products are shown. But when we select any product the chart is filtered and we do not want that. In order to highlight the products we do the following

We have managed to highlight the products but we do not stop here. We want to know in which years is the selected product the top selling product. And we will use strategic colouring to achieve it.

For this we create a copy of the Products table and call it Products 2 and define four measures as follows

TopProduct =
VAR topprod =
    TOPN ( 1, VALUES ( Products[Product] ), [Total Sales] )
RETURN
    topprod

Total Sales Top Product =
VAR table1 =
    SUMMARIZE (
        Sales,
        ‘Date'[Year],
        Products[ProductID],
        “SalesProducts”, [Total Sales]
    )
RETURN
    IF (
        [TopProduct] = SELECTEDVALUE ( ‘Produts 2′[Product] ),
        0,
        MAXX ( table1, [SalesProducts] )
    )

Total Sales Top Product =
VAR table1 =
    SUMMARIZE (
        Sales,
        ‘Date'[Year],
        Products[ProductID],
        “SalesProducts”, [Total Sales]
    )
RETURN
    IF (
        [TopProduct] = SELECTEDVALUE ( ‘Produts 2′[Product] ),
        0,
        MAXX ( table1, [SalesProducts] )
    )

Total Sales Other Products =
[Total Sales] – [Total Sales Top Product] – [Total Sales Selected Product]

We place the last three measures on a stacked column chart under Value and drag Year into Axis. We make the [Total Sales Selected Product] green so that it stand out and the other two shades of grey. Now you can use the same filter from above to select a product and see in which years it is the top selling product. There are some products in the overall top 10 which were never the top selling product in any year.

Part 1 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-1-comparing-different-metrics-across-a-common-dimension/

Part 2 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-2-comparing-a-trend-versus-the-rest/

Part 3 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-3-isolating-a-category-in-a-trend/

Part 4- https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-4-isolating-and-visualising-ytd-data/

Part 5 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-5-difference-in-sales-from-a-base-year-for-different-segments/

Part 6 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-6-visually-showcasing-the-years-in-which-a-selected-product-is-the-top-product/

Part 7 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-7-dynamically-plotting-yearly-percentage-sales-of-top-n-products-and-measuring-against-a-dynamic-target/

Part 8 – https://capstoneanalytics.com.au/strategic-colouring-in-power-bi-part-8-transforming-a-stacked-column-chart-to-highlight-individual-series/

Link to Github repo – https://github.com/capstoneanalytics/Power-BI-Strategic-Colouring

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the fourth post, we discussed how to isolate and visualise YTD data

In this post we will discuss how to visualise differences in sales for various categories in a field (Segment) across all the years in a model from a base year.

Our model has one fact table Sales and two dimension tables Date and Product

Define Total Sales as

Total Sales =
SUM ( Sales[Revenue] )

Next we will create a copy of the Date table and call it Date 2 and define these three measures

SelectedBaseYear =
SELECTEDVALUE ( ‘Date 2′[Year] )

BaseYearValue =
IF ( [SelectedBaseYear] = SELECTEDVALUE ( ‘Date'[Year] ), 0, BLANK () )

BaseYearSales =
CALCULATE ( [Total Sales], TREATAS ( VALUES ( ‘Date 2′[Year] ), ‘Date'[Year] ) )

SelectedBaseYear gives the Year when selected from a slicer. BaseYearValue will be used to highlight the SelectedBaseYear in the chart. BaseYearSales gives the Total Sales for the SelectedBaseYear

Now we define the variance measures

VarianceFromBaseYearNegative =
VAR diff = [Total Sales] – [BaseYearSales]
RETURN
    IF ( diff < 0, diff, 0 )

VarianceFromBaseYearPositive =
VAR diff = [Total Sales] – [BaseYearSales]
RETURN
    IF ( diff > 0, diff, 0 )

We also need to calculate the Maximum and Minimum differences so that we can highlight them in the chart

MaxPositiveDifference =
VAR baseyearsales = [BaseYearSales]
VAR result =
    CALCULATE (
        MAXX (
            SUMMARIZE ( Sales, ‘Date'[Year], “Variance”, [Total Sales] – baseyearsales ),
            [Variance]
        ),
        ALL ( ‘Date'[Year] )
    )
RETURN
    IF ( result = [VarianceFromBaseYearPositive], result, 0 )

MaxNegativeDifference =
VAR baseyearsales = [BaseYearSales]
VAR result =
    CALCULATE (
        MINX (
            SUMMARIZE ( Sales, ‘Date'[Year], “Variance”, [Total Sales] – baseyearsales ),
            [Variance]
        ),
        ALL ( ‘Date'[Year] )
    )
RETURN
    IF ( result = [VarianceFromBaseYearNegative], result, 0 )

Now we need to calculate two more measures so that we dont double up on the numbers

PositiveVarianceWithoutMax =
IF (
    [VarianceFromBaseYearPositive] = [MaxPositiveDifference],
    0,
    [VarianceFromBaseYearPositive]
)

NegativeVarianceWithoutMax =
IF (
    [VarianceFromBaseYearNegative] = [MaxNegativeDifference],
    0,
    [VarianceFromBaseYearNegative]
)

Drag a Line and Stacked Column chart into a blank canvas and drag the following fields (Year is from Date table)

The colours are formatted to something similar

Now drag Year from Date 2 table and drag it into a slicer and make it single select

Also drag Segment from Product table and drag it into a slicer and make it single select

Now you can select the Year which will serve as the Base Year and select different categories in the Segment field to look at the variances.

Link to interactive report here

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the previous post, we looked at how to isolate a category in a trend

We will add on this in this post and see how to isolate and visualise YTD data.

We have a simple data model with a sales table and a date table. There is sales data for 16 years in the model and we want to visualise the YTD performance for each year.

We define two measure as follows

Total Sales =
SUM ( Sales[Revenue] )

YTD Sales =
TOTALYTD ( [Total Sales], ‘Date'[Date] )

Next drag a line chart into the canvas and drag Date into Axis and [YTD Sales] into Values. The chart looks like this

Not quite what we wanted but the chart does exactly what its supposed to be doing. It calculates the YTD for year 2000 and when it reaches January 1 2001 it resets and starts from 0 and continues for the next year. This happens for all the years in the model.

What we want is a chart which show the YTD for each year starting from 0 so that they can be compared against each other. We can easily achieve this. Remove the Date filed and drag MonthName into the Axis and drag Year into Legend. The chart looks like this

This is exactly what we were after. Each YTD starts at 0 and now we can compare the performance of each years’ YTD against the other years. But the problem is there is too much data and its hard to focus on one year.

This is where we apply the concepts of strategic colouring. For this we need to define a measure to calculate the YTD for each year. For ex

YTD Sales 2000 =
VAR selyear = 2000
RETURN
    IF (
        selyear IN VALUES ( ‘Date'[Year] ),
        CALCULATE ( [YTD Sales], ‘Date'[Year] = selyear ),
        BLANK ()
    )

Use the logic above and calculate YTD for all the years for which there is Sales in the model. This has to be done manually currently, hopefully with the introduction of calculated groups this can be automated in the future. In our case we have defined 16 YTD measures from 2000 to 2015

Create a copy of the Date table and call it Date 2. Next define this measure

TotalSalesAmountSelectedYear =
IF (
    ISFILTERED ( ‘Date 2′[Year] ),
    CALCULATE ( [YTD Sales], TREATAS ( VALUES ( ‘Date 2′[Year] ), ‘Date'[Year] ) ),
    BLANK ()
)

In the line chart above remove the Year from legend and drag the 16 measures and the above measures into Values and make the colour of the 16 YTD measures as grey and the above measure as green

Next drag Year from Date 2 table into a slicer and with some formatting the chart should look like this when Year 2000 is selected

We can to one step further and pick the range of years we want to analyse. For this place the Year from Date table into another slicer and place it above the slicer created above. We can now narrow down our focus by selecting range of years in the first slicer. We also want to make sure that when we select a range the second slicer is also filtered. For this we define a measure called

FilteredYear =
VAR selyear =
    VALUES ( ‘Date'[Year] )
RETURN
    IF ( MAX ( ‘Date 2′[Year] ) IN selyear, 1, 0 )

Place this measure as a filter on the bottom slicer and set it to be equal to 1.

Now whenever the range in the top slicer changes it will filter the bottom slicer. You can then chose the year from the bottom slicer to isolate the YTD for the year of your choice.
Add some text for user prompt and the final setup looks like this after a few selections are made

Link to interactive report here

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the previous post we saw how to compare a trend of one or multiple category in a field versus the rest of the categories.

In this part we will see how to isolate a category in a trend

For this we need two measures and one new table

Define a new table as folllows

ProductSize =
VALUES ( dimProduct[Size] )

Define the two measures as follows

TotalSalesAmount =
SUM ( fctSales[SalesAmount] )

TotalSalesAmountSelectedSize =
IF (
    ISFILTERED ( ProductSize[Size] ),
    CALCULATE (
        [TotalSalesAmount],
        TREATAS ( VALUES ( ProductSize[Size] ), dimProduct[Size] )
    ),
    BLANK ()
)

Now we are ready to visualise

In a line chart Drag Monthname into Axis and [TotalSalesAmount] into Values and dimProduct[Size] into Legend. Make the colours of all the lines grey and under Format-> Y axis change start to 0 and End to 500000. This way we are defining the start and end points and they do not change

Copy the visual. Remove the legend and Values and drag [TotalSalesAmountSelectedSize] into Values. Make the colour a bit brighter like green or blue.

Now here is the hack to make it work. Click on the first visual and under Format-> General, note the values. They will be something like this

Now select the second visuals and copy – paste the values from above into the Format-> General section. Now both the visuals are on top of the other. You have to make sure that the second visual is in front and the first one is at the back. You can use the Format – Bring forward/Bring backward to achieve this.

Next drag the  ProductSize[Size] into a slicer visual and make it single select. Happy interrogating !

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

In the first post, we discussed how to use strategic colouring to compare different metrics over a common dimension.

In this part I will talk about how to compare a trend of one or multiple category in a field versus the rest of the categories.

We will use the same dataset as in the previous part for continuity. Define 3 measures as follows

TotalSalesAmount =
SUM ( fctSales[SalesAmount] )

TotalSalesAmountALLSize =
CALCULATE ( [TotalSalesAmount], ALL ( dimProduct[Size] ) )

TotalSalesAmountRest =
[TotalSalesAmountALLSize] – [TotalSalesAmount]

Drag the stacked area chart into the canvas and place MonthName in Axis and  [TotalSalesAmount] and [TotalSalesAmountRest] measures in Values. Change the colour of [TotalSalesAmountRest] to grey and [TotalSalesAmount] to a brighter colour say green or blue

Drag Sizze from DimProduct into a Slicer visual and start interrogating the data.

https://capstoneanalytics.com.au/master-post-for-strategic-colouring-articles/

So you work in Sales. You want to compare revenue, profit, tax amount over the different business units. You want to see the relative position of a business unit over the other units for the three metrics . How would you do it ? This was precisely what one of our client was after. The following is a solution we provided. The Adventureworks dataset is used in this article to explain the concepts.

We will be visualising SalesAmount, OrderQuantity, and TaxAmt over the Product Size. I have chosen Product Size as the common dimension as there are more than 10 sizes and thus helps to get the point across.

Define 3 measures for the three metrics as follows

TotalSalesAmount =
SUM (  fctSales[SalesAmount] )

TotalOrderQuantity =
SUM ( fctSales[OrderQuantity] )

TotalTaxAmount =
SUM ( fctSales[TaxAmt] )

Next create a new table called ProductSize as follows. The column size will be used as a slicer in our report

ProductSize =
VALUES ( dimProduct[Size] )

Next place a clustered bar chart on a blank page. Drag DimProduct[Size] into the Axis field and drag [TotalSalesAmount] into the Vaue field. Make the data colour “#E6E6E6”. Go to the Analytics pane on the visual and add an Average line and show labels.

Repeat the above for [TotalOrderQuantity] and [TotalTaxAmount]. Your canvas should look like this

The aim is to apply conditional formatting on the bars so that it gives different colours when a bar is above or below the average, We need to define three measures to calculate the averages.

Average Sales =
CALCULATE (
    AVERAGEX (
        SUMMARIZE ( fctSales, dimProduct[Size], “SalesTotal”, [TotalSalesAmount] ),
        [SalesTotal]
    ),
    ALL ( dimProduct[Size] ),
    NOT ( ISBLANK ( dimProduct[Size] ) )
)

Average Orderquantity =
CALCULATE (
    AVERAGEX (
        SUMMARIZE ( fctSales, dimProduct[Size], “QuantityTotal”, [TotalOrderQuantity] ),
        [QuantityTotal]
    ),
    ALL ( dimProduct[Size] ),
    NOT ( ISBLANK ( dimProduct[Size] ) )
)

Average Tax =
CALCULATE (
    AVERAGEX (
        SUMMARIZE ( fctSales, dimProduct[Size], “TaxTotal”, [TotalTaxAmount] ),
        [TaxTotal]
    ),
    ALL ( dimProduct[Size] ),
    NOT ( ISBLANK ( dimProduct[Size] ) )
)

The NOT ( ISBLANK ( dimProduct[Size] ) )  is used as I want to remove all the sizes which dont have a value in them

Next we will be defining three measures to get the right colours for the bars

SalesColour =
VAR selsize =
    SELECTEDVALUE ( ProductSize[Size] )
RETURN
    IF (
        SELECTEDVALUE ( dimProduct[Size] ) = selsize
            && [TotalSalesAmount] < [Average Sales],
        “#FD625E”,
        IF (
            SELECTEDVALUE ( dimProduct[Size] ) = selsize
                && [TotalSalesAmount] > [Average Sales],
            “#003DFF”,
            “#E6E6E6”
        )
    )

OrderQuantityColour =
VAR selsize =
    SELECTEDVALUE ( ProductSize[Size] )
RETURN
    IF (
        SELECTEDVALUE ( dimProduct[Size] ) = selsize
            && [TotalOrderQuantity] < [Average Orderquantity],
        “#FD625E”,
        IF (
            SELECTEDVALUE ( dimProduct[Size] ) = selsize
                && [TotalOrderQuantity] > [Average Orderquantity],
            “#003DFF”,
            “#E6E6E6”
        )
    )

TaxColour =
VAR selsize =
    SELECTEDVALUE ( ProductSize[Size] )
RETURN
    IF (
        SELECTEDVALUE ( dimProduct[Size] ) = selsize
            && [TotalTaxAmount] < [Average Tax],
        “#FD625E”,
        IF (
            SELECTEDVALUE ( dimProduct[Size] ) = selsize
                && [TotalTaxAmount] > [Average Tax],
            “#003DFF”,
            “#E6E6E6”
        )
    )

Now we are ready to apply conditional formatting. Select the first chart on the canvas and under Format go to Data colours and click on the three dots under Default colour and click conditional formatting. In the window that comes up select the following options and click OK

Repeat the above procedure for the second and third chart and replace SalesColour by OrderColour and TaxColour respectively

The charts are now conditionally formatted. Drag a slicer into the canvas and make it Single select. Drag ProductSize[Size] into the canvas (Remember to drag the right size column, the DimProduct[Size] should not be dragged here).

Select a size in the slicer and see the magic of selective colouring unfold.